My answer was, of course, “Let me have a look and get back to you.”

I went to my favourite dev tool, Xojo, and went through the process of developing a solution. The connection is a REST API, so I’ll start with a web project and use the HandleURL event. And I’ll use a URLConnection to pass on the request.  Wait … could it be that simple?

Function HandleURL(request As WebRequest, response As WebResponse) Handles HandleURL as Boolean

  // Create the outbound connection
  Var connector As New URLConnection
 
  // Copy the content of the request
  connector.SetRequestContent(request.Body, request.MIMEType)

  // Send the request
  Var result As String
  Try
    result = connector.SendSync("POST", kAddress + request.Path)
  Catch err As RuntimeException
    // Catch DNS, Certificate & Timeout errors
    response.Status = 500
    response.Write(err.Message)
    Return True
  End

  // Return the result of the request
  response.Status = connector.HTTPStatusCode
  response.Write(result)

  Return True

End Function

The answer is, “Yes!”  This is all the code in the entire project.

You will notice that there is no security, but in this instance that is fine as the virtual machine is running this is on the same network as the client server and the firewall is configured to only allow connections from that server.

After processing over 60 thousand requests, memory use is 7.3MB and never exceeded 13MB. CPU usage was at the maximum 1.5%.

Even after using Xojo for 20 years this still blows my mind.

Wayne Golding has been a Xojo developer since 2005 and is a Xojo MVP. He operates the IT Company Axis Direct Ltd which primarily develops applications using Xojo that integrate with Xero www.xero.com. Wayne’s hobby is robotics where he uses Xojo to build applications for his Raspberry Pi, often implementing IoT for remote control.

• Facebook
• X
• LinkedIn
• GitHub
• YouTube

If you’re familiar with the command-line tool curl, you may wonder how to use curl in Xojo effectively. Curl is a powerful tool for making HTTP requests, but it’s not always the most convenient for working within a graphical application like Xojo.

That’s where Xojo’s URLConnection class shines! It provides a simple and elegant way to make HTTP requests directly from your Xojo code, making it easy to use curl in Xojo.

In this post, you will learn how to adapt common curl commands to Xojo’s URLConnection. Let’s get started.

Basic GET Request Using Curl in Xojo

Meaning: Fetch the content of the specified URL using a GET request.

curl https://example.com

Var socket As New URLConnection
Var response As String = socket.SendSync("GET", "https://example.com", 30)

GET Request with Query Parameters

Meaning: Fetch the content of the specified URL with query parameters.

curl "https://example.com?param1=value1&param2=value2"

Var socket As New URLConnection
Var response As String = socket.SendSync("GET", "https://example.com?param1=value1&param2=value2", 30)

Var socket As New URLConnection

// Define the query parameters using Pair
Var queryParams() As Pair
queryParams.Add("param1" : "value1")
queryParams.Add("param2" : "value2")

// Construct the URL with query parameters
Var baseURL As String = "https://example.com"
Var queryString As String = "?"

For Each param As Pair In queryParams
  queryString = queryString + param.Left + "=" + param.Right + "&"
Next

// Remove the trailing '&' character
queryString = queryString.Left(queryString.Length - 1)

// Combine base URL and query string
Var fullURL As String = baseURL + queryString

Var response As String = socket.SendSync("GET", fullURL, 30)

Adding Headers

Meaning: Send a GET request with a custom header.

curl -H "Content-Type: application/json" https://example.com

Var socket As New URLConnection
socket.RequestHeader("Content-Type") = "application/json"
Var response As String = socket.SendSync("GET", "https://example.com", 30)

Sending JSON Data with POST

Meaning: Send a POST request with JSON data to the specified URL.

curl -L 'http://example.com' ^
-H 'Content-Type: application/json' ^
-d '{"key1":"value1","key2":"value2"}'

Var socket As New URLConnection
Var jsonData As String = "{""key1"":""value1"",""key2"":""value2""}"
socket.SetRequestContent(jsonData, "application/json")
Var response As String = socket.SendSync("POST", "https://example.com", 30)

Var socket As New URLConnection
// Create a new JSONItem
Var json As New JSONItem

// Add key-value pairs to the JSONItem
json.Value("key1") = "value1"
json.Value("key2") = "value2"

socket.SetRequestContent(json.ToString, "application/json")
Var response As String = socket.SendSync("POST", "https://example.com", 30)

Basic Authentication

Meaning: Send a GET request with basic authentication.

curl -u username:password http://example.com

Var socket As New URLConnection
socket.RequestHeader("Authorization") = "Basic " + EncodeBase64("username:password")
Var response As String = socket.SendSync("GET", "https://example.com", 30)

Download a File

Meaning: Download a file from the specified URL and save it with the given filename.

curl -o filename https://example.com/file.zip

Var socket As New URLConnection
Var outputFile As FolderItem = SpecialFolder.Desktop.Child("file.zip")
socket.SendSync("GET", "https://example.com/file.zip", outputFile, 30)

Custom Request Methods

Meaning: Send a DELETE request to the specified URL (you can replace DELETE with any other method required, PUT, PATCH…)

curl -X DELETE https://example.com/resource

Var socket As New URLConnection
Var response As String = socket.SendSync("DELETE", "https://example.com/resource", 30)

As you’ve seen, using curl in Xojo with the URLConnection class is a breeze.

Whether you’re fetching data, sending/receiving JSON payloads, or downloading files, the examples provided in this tutorial offer a solid foundation for integrating web services into your Xojo applications. As you continue to experiment with URLConnection, you’ll discover even more ways to enhance your projects and improve your workflow.

If you found this tutorial helpful, don’t forget to share it with your fellow developers and colleagues.

Gabriel is a digital marketing enthusiast who loves coding with Xojo to create cool software tools for any platform. He is always eager to learn and share new ideas!

• Facebook
• X
• LinkedIn
• GitHub
• YouTube

RESTy uses the URLConnection class to send a request to a web service and get a result. If the result is text (JSON, for example) it displays in the Response tab. Here, I am calling the Eddie’s Electronics web service to return a list of all the customers by specifying the URL and clicking the Fetch button:

For other data (binary data such as pictures) you can use the Fetch to File button to save the request to a file.

The Authentication tab is used to provide Basic Authentication should the web service require it.

The Request Content tab can be used to provide Content data that the request might need. For example, the Eddie’s Electronics web service also lets you request the details for a specific customer by providing simple JSON containing the customer ID. To try this using RESTy app:

1. Click on the Request Content Tab.
2. To indicate the customer you wish to retrieve, enter the following JSON into the field on that tab: {"ID": 10039}
3. Select POST from the Send Method popup menu.
4. In the URL field, enter: https://eews-demos.xojo.com/GetCustomer
5. Press the Fetch button.

If you have entered everything correctly, will see the data for Caleb Horn in JSON format:

And to see the JSON formatted nicely, click the Format JSON button:

This will let you you explore calling various REST API services. You can explore the source code to see how it uses URLConnection to do so.

To be sure, RESTy is very basic, but you have the source code so you and add features to it and modify it for your own testing needs.